[Navigation] Create a dedicated 2D navigation server

* Add a dedicated 2D server * Create dedicated tests * Split performance metrics between 2D and 3D * Rename the 3D only server module
2025-02-26 11:48:13 +01:00
parent 7598b08ec2
commit 5cc0539961
90 changed files with 8083 additions and 910 deletions
--- a/modules/navigation_3d/SCsub
+++ b/modules/navigation_3d/SCsub
@ -0,0 +1,87 @@
+#!/usr/bin/env python
+from misc.utility.scons_hints import *
+
+Import("env")
+Import("env_modules")
+
+env_navigation_3d = env_modules.Clone()
+
+# Thirdparty source files
+
+thirdparty_obj = []
+navigation_2d_enabled = "navigation_2d" in env.module_list
+
+# Recast Thirdparty source files
+if env["builtin_recastnavigation"]:
+    thirdparty_dir = "#thirdparty/recastnavigation/Recast/"
+    thirdparty_sources = [
+        "Source/Recast.cpp",
+        "Source/RecastAlloc.cpp",
+        "Source/RecastArea.cpp",
+        "Source/RecastAssert.cpp",
+        "Source/RecastContour.cpp",
+        "Source/RecastFilter.cpp",
+        "Source/RecastLayers.cpp",
+        "Source/RecastMesh.cpp",
+        "Source/RecastMeshDetail.cpp",
+        "Source/RecastRasterization.cpp",
+        "Source/RecastRegion.cpp",
+    ]
+    thirdparty_sources = [thirdparty_dir + file for file in thirdparty_sources]
+
+    env_navigation_3d.Prepend(CPPPATH=[thirdparty_dir + "Include"])
+
+    env_thirdparty = env_navigation_3d.Clone()
+    env_thirdparty.disable_warnings()
+    env_thirdparty.add_source_files(thirdparty_obj, thirdparty_sources)
+
+# RVO 2D Thirdparty source files
+if env["builtin_rvo2_2d"]:
+    thirdparty_dir = "#thirdparty/rvo2/rvo2_2d/"
+    thirdparty_sources = [
+        "Agent2d.cpp",
+        "Obstacle2d.cpp",
+        "KdTree2d.cpp",
+        "RVOSimulator2d.cpp",
+    ]
+    thirdparty_sources = [thirdparty_dir + file for file in thirdparty_sources]
+
+    env_navigation_3d.Prepend(CPPPATH=[thirdparty_dir])
+
+    # Don't build rvo_2d if 2D navigation is enabled.
+    if not navigation_2d_enabled:
+        env_thirdparty = env_navigation_3d.Clone()
+        env_thirdparty.disable_warnings()
+        env_thirdparty.add_source_files(thirdparty_obj, thirdparty_sources)
+
+# RVO 3D Thirdparty source files
+if env["builtin_rvo2_3d"]:
+    thirdparty_dir = "#thirdparty/rvo2/rvo2_3d/"
+    thirdparty_sources = [
+        "Agent3d.cpp",
+        "KdTree3d.cpp",
+        "RVOSimulator3d.cpp",
+    ]
+    thirdparty_sources = [thirdparty_dir + file for file in thirdparty_sources]
+
+    env_navigation_3d.Prepend(CPPPATH=[thirdparty_dir])
+
+    env_thirdparty = env_navigation_3d.Clone()
+    env_thirdparty.disable_warnings()
+    env_thirdparty.add_source_files(thirdparty_obj, thirdparty_sources)
+
+
+env.modules_sources += thirdparty_obj
+
+# Godot source files
+
+module_obj = []
+
+env_navigation_3d.add_source_files(module_obj, "*.cpp")
+env_navigation_3d.add_source_files(module_obj, "3d/*.cpp")
+if env.editor_build:
+    env_navigation_3d.add_source_files(module_obj, "editor/*.cpp")
+env.modules_sources += module_obj
+
+# Needed to force rebuilding the module files when the thirdparty library is updated.
+env.Depends(module_obj, thirdparty_obj)